メインコンテンツへスキップ
見出し画像

ブッダブロと仲間たち

    108Hassium

    どうも、108Hassiumです。

    この記事では、「ブッダブロ」という有名なフラクタル図形や関連する別のフラクタル図形を紹介します。

    定義・描画法

    ブッダブロはこんな形のフラクタル図形です。

    画像
    ☝ブッダブロ

    皆さんお馴染みのマンデルブロ集合はz0=0,zn+1=zn2+cz_0=0,z_{n+1}=z_n^2+cという数列が無限大に発散するかどうかで複素平面を塗り分けたものですが、ブッダブロは同じ数列を使って「znz_nが発散する場合だけz0,z1,z2…z_0,z_1,z_2…をプロットする」という操作をccを変えながら繰り返したものです。

    この説明におおよそ忠実にコードを書くと、以下のようになります。

    void setup(){
  size(2000,2000);
  background(0);
  stroke(255,5);
  double x,y,px,py,cx,cy;
  boolean o=true;
  for(int a=0;a<4000;a++){
    for(int b=0;b<4000;b++){
      cx=(double)a/1000.0-2.0;
      cy=(double)b/1000.0-2.0;
      x=cx;
      y=cy;
      o=true;
      for(int c=0;c<50000&&o;c++){
        px=x;
        py=y;
        x=px*px-py*py+cx;
        y=2.0*px*py+cy;
        if(x*x+y*y>4){
          o=false;
        }
      }
      if(!o){
        x=cx;
        y=cy;
        o=true;
        for(int c=0;c<50000&&o;c++){
          px=x;
          py=y;
          x=px*px-py*py+cx;
          y=2.0*px*py+cy;
          point((float)(x+2.0)*500.0,(float)(y+2.0)*500.0);
          if(x*x+y*y>4){
            o=false;
          }
        }
      }
    }
  }
}

    ※言語はProcessing

    詳しい内容の解説は省略しますが、以下の記事で解説しているものと大体同じ仕組み(変数名は全然違いますが)なので気になる人は読んでみてください。

    なお、wikipediaの説明ではccの値は一定範囲内からランダムに決めると書いてありますが、先程のコードでは格子状にとった点を総当たりして発散する点を探すような仕様にしてあります。

    これは「成果物にランダム性が出ないものに乱数を使いたくない」という私の好みによるものです。

    さて、先程のコードを実行すると以下のような画像が生成されます。

    画像

    冒頭のカラーの画像は、少し違った方法で描画されています。

    void setup(){
  size(2000,2000);
  background(0);
  noStroke();
  double x,y,px,py,cx,cy,dx=0,dy=0;
  int[][][] ar=new int[2000][2000][3];
  boolean o=true;
  for(int a=0;a<2000;a++){
    for(int b=0;b<2000;b++){
      ar[a][b][0]=0;
      ar[a][b][1]=0;
      ar[a][b][2]=0;
    }
  }
  for(int a=0;a<20000;a++){
    for(int b=0;b<20000;b++){
      cx=(double)a/5000.0-2.0;
      cy=(double)b/5000.0-2.0;
      x=0;
      y=0;
      o=true;
      for(int c=0;c<50000&&o;c++){
        px=x;
        py=y;
        x=px*px-py*py+cx;
        y=2.0*px*py+cy;
        if(c%100==0){
          dx=x;
          dy=y;
        }else if((x-dx)*(x-dx)+(y-dy)*(y-dy)<1e-10){
          c=50000;
        }
        if(x*x+y*y>4){
          o=false;
        }
      }
      if(!o){
        x=0;
        y=0;
        o=true;
        for(int c=0;c<50000&&o;c++){
          px=x;
          py=y;
          x=px*px-py*py+cx;
          y=2.0*px*py+cy;
          if(0<(x+2.0)*500.0&&(x+2.0)*500.0<2000&&0<(y+2.0)*500.0&&(y+2.0)*500.0<2000){
            if(c<500){
              ar[(int)((x+2.0)*500.0)][(int)((y+2.0)*500.0)][0]++;
            }else if(c<5000){
              ar[(int)((x+2.0)*500.0)][(int)((y+2.0)*500.0)][1]++;
            }else{
              ar[(int)((x+2.0)*500.0)][(int)((y+2.0)*500.0)][2]++;
            }
          }
          if(x*x+y*y>4){
            o=false;
          }
        }
      }
    }
  }
  for(int a=0;a<2000;a++){
    for(int b=0;b<2000;b++){
      fill(ar[a][b][0]/5,ar[a][b][1]/5,ar[a][b][2]/5);
      rect(a,b,1,1);
    }
  }
}

    RGB値を格納する配列を画像の1ピクセルずつに対して用意し、znz_nの位置に点を打つ代わりに配列の中身を1ずつ増やして、数列の計算が全て終わってから配列の値を使って画像を描画しています。

    色の決定にはznz_nのnn(プログラム中ではc)の値が使われ、nnが0～499のときは赤、500～4999のときは緑、それ以外は青の値を増やします。

    なお、wikipediaではカラー画像を「ネブラブロ」と呼ぶことがあるという記述がありますが、わざわざ呼び分ける必要性を感じないのでこの記事ではカラーのものもブッダブロと呼ぶことにします。

    バリエーション

    本来のブッダブロは「マンデルブロ集合」という概念と同様にz2+cz^2+cという関数と紐づけられた存在ですが、この記事では普段の私のマンデルブロ集合の扱いと同様に、別の関数を使ったものもブッダブロと呼ぶことにします。(今までのものは「z2+cz^2+cのブッダブロ」になります)

    というわけで、いろいろな関数によるブッダブロを紹介します。

    画像
    ☝z^3+cのブッダブロ
    画像
    ☝z^4+cのブッダブロ

    zn+cz^n+cのブッダブロです。

    zn+cz^n+cのマンデルブロ集合と同じくn−1n-1回回転対称になるようです。

    画像
    ☝con(z)^2+cのブッダブロ

    マンデルブロ集合では何もなかった部分に現れる赤いトゲが特徴的です。

    画像
    ☝c/(z^2-1)+1のブッダブロ(x=-4~4,y=-4~4)

    cz2−1+1\frac{c}{z^2-1}+1といえば網目状の模様が特徴ですが、ブッダブロには表れないようです。

    画像
    ☝z^3/3-z^2/2+cのブッダブロ(z_0=0)
    画像
    ☝z^3/3-z^2/2+cのブッダブロ(z_0=1)
    画像
    ☝z^3/3-z^2/2+cのマンデルブロ集合(z_0=0)

    z33−z23+c\frac{z^3}{3}-\frac{z^2}{3}+cのマンデルブロ集合はジュリア集合のようなガタガタの輪郭が特徴ですが、よく見るとブッダブロでも同じ特徴が表れています。

    画像
    ☝(1+0.1i)(z+1/z)+cのブッダブロ(z_0=1,x=-2~2,y=-2~2)
    画像
    ☝(1+0.1i)(z+1/z)+cのマンデルブロ集合(z_0=1,x=-2~2,y=-2~2)

    他のものと同様にマンデルブロ集合に似たシルエットが現れましたが、何故か位置がずれています。

    画像
    ☝z^2+ixy+cのブッダブロ
    画像
    ☝(x+y+a,xy+b)のブッダブロ((x_0,y_0)=(-1,0))

    con(z)2+c\text{con}(z)^2+cのものもそうですが、非解析的関数のブッダブロは解析的関数のものとはかなり違った見た目になるようです。

    アンチブッダブロ？

    ブッダブロ(狭義の方)はzn+1=zn2+cz_{n+1}=z_n^2+cという数列のうち発散するものの値を使って描画されるものですが、逆に収束するもので同じことをすると以下のような画像が得られました。

    画像

    ソースコードは以下の通りです。

    void setup(){
  size(2000,2000);
  background(0);
  noStroke();
  double x,y,px,py,cx,cy,dx=0,dy=0;
  int[][][] ar=new int[2000][2000][3];
  boolean o=true;
  for(int a=0;a<2000;a++){
    for(int b=0;b<2000;b++){
      ar[a][b][0]=0;
      ar[a][b][1]=0;
      ar[a][b][2]=0;
    }
  }
  for(int a=0;a<20000;a++){
    for(int b=0;b<20000;b++){
      cx=(double)a/5000.0-2.0;
      cy=(double)b/5000.0-2.0;
      x=0;
      y=0;
      o=true;
      for(int c=0;c<5000&&o;c++){
        px=x;
        py=y;
        x=px*px-py*py+cx;
        y=2.0*px*py+cy;
        if(c%100==0){
          dx=x;
          dy=y;
        }else if((x-dx)*(x-dx)+(y-dy)*(y-dy)<1e-10){
          c=50000;
        }
        if(x*x+y*y>4){
          o=fals;
        }
      }
      if(o){
        x=0;
        y=0;
        o=true;
        for(int c=0;c<5000&&o;c++){
          px=x;
          py=y;
          x=px*px-py*py+cx;
          y=2.0*px*py+cy;
          if(0<(x+2.0)*500.0&&(x+2.0)*500.0<2000&&0<(y+2.0)*500.0&&(y+2.0)*500.0<2000){
            if(c<50){
              ar[(int)((x+2.0)*500.0)][(int)((y+2.0)*500.0)][0]++;
            }else if(c<500){
              ar[(int)((x+2.0)*500.0)][(int)((y+2.0)*500.0)][1]++;
            }else{
              ar[(int)((x+2.0)*500.0)][(int)((y+2.0)*500.0)][2]++;
            }
          }
          if(x*x+y*y>4){
            o=false;
          }
        }
      }
    }
  }
  for(int a=0;a<2000;a++){
    for(int b=0;b<2000;b++){
      fill(ar[a][b][0]/50,ar[a][b][1]/50,ar[a][b][2]/50);
      rect(a,b,1,1);
    }
  }
}

    主な変更点としては、発散しない数列を描画に使うようにしていること以外にはcの上限を50000から5000に減らし、それに合わせて彩色に関する値を調整している、というものがあります。

    wikipediaのブッダブロのページでは、説明は意味不明なもののこの画像とよく似たものが「アンチブッダブロ」という名前で紹介されています。

    というわけで、この記事では「ブッダブロの収束列バージョン」のことをアンチブッダブロと呼ぶことにします。

    画像
    ☝z^3+cのアンチブッダブロ
    画像
    ☝z^4+cのアンチブッダブロ
    画像
    ☝c/(z^2-1)+1のアンチブッダブロ

    この辺は特に説明することも無いです。

    画像
    ☝z^3/3-z^2+cのアンチブッダブロ(z_0=0)

    z33−z23+c\frac{z^3}{3}-\frac{z^2}{3}+cのマンデルブロ集合とブッダブロにはジュリア集合のような見た目の部分があるというのはすでに説明した通りですが、アンチブッダブロではさらに顕著にジュリア集合っぽさが出ます。

    画像
    ☝c(z+1/z)のアンチブッダブロ(z_0=1)

    c(z+1z)c(z+\frac{1}{z})のブッダブロは綺麗に描画できなかったのですが、アンチブッダブロはこうなりました。

    画像
    ☝con(z)^2+cのアンチブッダブロ
    画像
    ☝z^2+ixy+cのアンチブッダブロ
    画像
    ☝(x+y+a,xy+b)のアンチブッダブロ((x_0,y_0)=(-1,0))

    非解析的関数のアンチブッダブロはやはり独特です。

    画像

    複素平面の下半分の値だけを使って描画した、z2+cz^2+cのアンチブッダブロです。

    どうやら中央の大きな円状の構造の下にも、細かい模様が隠れているようです。

    ちなみにブッダブロで同じことをすると以下のようになります。

    画像
     
     
     

    108Hassium

     
     
    数学関係の記事を書きます。毎週日曜更新予定。

    あなたへのおすすめ